home *** CD-ROM | disk | FTP | other *** search
/ Cream of the Crop 11 / Cream of the Crop 11-1.iso / games / nerak2.zip / CURRITEM.SCR < prev    next >
Text File  |  1995-09-24  |  41KB  |  1,228 lines
  1. !
  2. ! Script Name: CURRITEM.SCR
  3. !
  4. ! This script may be called by any script (using 'runscript') to handle
  5. ! actions on objects pointed to by the generic CURRITEM object, which
  6. ! may point to any object being carried by a player or NPC character
  7. ! in it's backpack (PLAYER.BP or NPC.PB) or being worn (or wielded)
  8. ! by the same (PLAYER.BODY, PLAYER.WEAPON, NPC.ARMOR, etc)
  9. !
  10. ! You cannot make CURRITEM point to 'OBJECT' since the object is not
  11. ! being carried, so a different script of almost identical structure
  12. ! (called DESCOBJ.SCR) is available for looking at those.
  13. !
  14. ! Before calling this script, you should make sure that the CURRITEM
  15. ! object is pointing to the right object.  Examples follow:
  16. !
  17. ! To 'look' at the weapon being worng by a player:
  18. !    curritem = player.weapon;
  19. !    runscript( player.weapon.script, "CURRITEM", LOOK );
  20. !
  21. ! To 'examine' the currently selected backpack item in an NPC's backpack
  22. !    curritem = npc.bp;
  23. !    runscript( npc.bp.script, "CURRITEM", EXAMINE );
  24. !   
  25. ! To 'examine' the vehicle being used by the party,
  26. !    curritem = group.vehicle;
  27. !    runscript( group.vehicle.script, "CURRITEM", EXAMINE );
  28. !
  29. ! To 'invoke' an scroll in the player's backpack, selecting the item
  30. ! from a menu of all scrolls being carried:
  31. !    L0 = select( player.bp, SCROLL );
  32. !    if L0 >= 0 then
  33. !      ! Note that 'curritem' was set by the select itself, so we don't
  34. !      ! have to assign 'curritem' at all.
  35. !      ! You could say 'curritem = player.bp' if you wanted to make
  36. !      ! it clear you expect curritem to be the currently selected backpack
  37. !      ! item.
  38. !      runscript( curritem.script, "CURRITEM", INVOKE );
  39. !    endif;
  40. ! 
  41. ! Remember that the CURRITEM generic object is changed everytime you
  42. ! perform one of the following actions:
  43. ! 
  44. ! ACTION                CHANGES TO CURRITEM
  45. ! --------------------  -------------------------------------------
  46. ! vanish(NPC)           if curritem belongs to NPC, it is left undefined
  47. ! curritem = x;         Direct assignment to one of the following:
  48. !                          group.vehicle
  49. !                          npc.bp, npc.body, npc.weapon, ..
  50. !                          player.bp, player.body, player.weapon, ..
  51. ! x = select( .. )      A menu selection from a player's or npc's 
  52. !                          bp or body set's curritem also!
  53. !   
  54. !------------------------------------------------------------------------!
  55. ! :@TALK   ! No talking in this script..
  56. !------------------------------------------------------------------------!
  57. ! :@GET    ! No getting in this script
  58. !------------------------------------------------------------------------!
  59. !------------------------------------------------------------------------!
  60. :@DROP      ! Drop the object on the floor !
  61. !------------------------------------------------------------------------!
  62.   if curritem.count > 1 then
  63.     L(0) = getnum( "How many? ", 0, curritem.count );
  64.     if L(0) > 0 then 
  65.       writeln( "You drop ", L(0), " ", curritem.name, "(s)" );
  66.       drop( curritem, L(0) );  
  67.     else
  68.       writeln( "None." );
  69.     endif;
  70.   else
  71.     writeln( "You drop the ", curritem.name );
  72.     drop( curritem );
  73.   endif;
  74.   STOP;
  75.  
  76. !------------------------------------------------------------------------!
  77. :@EXIT ! Exit a VEHICLE (since this is an object we are talking about..)
  78. !------------------------------------------------------------------------!
  79.   ! Since you can only ride one vehicle at a time, this portion of the
  80.   ! script assumes you want to exit from the vehicle being ridden, so 
  81.   ! we ignore 'curritem' and use 'group.vehicle' directly.
  82.   if group.vehicle.count = 0 then
  83.     writeln("You are already on foot!" );
  84.     STOP;
  85.   endif;
  86.   drop( group.vehicle );
  87.   voice( "Exit", 1000 );
  88.   writeln( "You are now on foot.." );
  89.   STOP;
  90.  
  91. !------------------------------------------------------------------------!
  92. :@WEAR   ! Wearing or wielding stuff
  93. !------------------------------------------------------------------------!
  94.  
  95.   L(0) = 0;  ! Hands needed to hold the item..
  96.  
  97.   on curritem.type goto
  98.    WR_FOOD,     WR_WEAPON,     WR_AMMO,      WR_ARMOR,      WR_SHIELD,
  99.    WR_AMULET,   WR_RING,       WR_POTION,    WR_SCROLL,     WR_STAFF;
  100. !
  101. ! the rest can't be worn, so no need to list them..
  102. !  WR_CHEST,    WR_KEYS,       WR_GEMS,      WR_BOOK,       WR_GOLDSACK,
  103. !  WR_TORCH,    WR_LANTERN,    WR_ROPE,      WR_HOOKS,      WR_MIRROR,
  104. !  WR_SIGN,     WR_VEHICLE
  105. !
  106.  
  107. :WR_FOOD
  108. :WR_AMMO
  109. :WR_POTION
  110. :WR_SCROLL
  111.    writeln( "How do you wear a ", curritem.type, "? " );
  112.    STOP;
  113.  
  114. :WR_WEAPON
  115.    gosub STILLKICKING;
  116.    if (player.class = ELF or player.class = WIZARD or player.class = ARCHER) 
  117.       and curritem.weight > 5 + adjustments(player.str) then
  118.      writeln( "This weapon is too heavy for this character class." );
  119.    elsif player.class = WIZARD and curritem.hands > 1 then
  120.      writeln( "Wizards can only use one-handed weapons" );
  121.    elsif (player.class = WIZARD or player.class = DWARF) and curritem.class = MISSILE then
  122.      writeln( "Wizards and dwarfs can't use non-magical missile weapons" );
  123.    elsif player.weapon.count > 0 then
  124.      writeln( "You must first remove the ", player.weapon.name );
  125.    else
  126.      L(0) = curritem.hands; ! Hands needed to hold the weapon !
  127.      S0 = "wielding";
  128.      goto WR_DOIT;
  129.    endif;
  130.    STOP;
  131.  
  132. :WR_ARMOR
  133.    gosub STILLKICKING;
  134.    if (player.class = ELF or player.class = WIZARD) and
  135.       curritem.weight > 5 + adjustments(player.str) then
  136.      writeln( "This armor is too heavy for an elf or a wizard" );
  137.    elsif player.class = ARCHER and
  138.       curritem.weight > 10 + adjustments(player.str) then
  139.      writeln( "This armor is too cumbersome for an archer" );
  140.    elsif player.armor.count > 0 then
  141.      writeln( "You must first remove the ", player.armor.name );
  142.    else
  143.      S0 = "wearing";
  144.      goto WR_DOIT;
  145.    endif;
  146.    STOP;
  147.  
  148. :WR_SHIELD
  149.    gosub STILLKICKING;
  150.    if player.class = WIZARD or player.class = ARCHER or player.class = DWARF then
  151.      writeln( player.class, "s cannot use a shield!" );
  152.    elsif player.class = ELF and curritem.weight > 5 + adjustments(player.str) then
  153.      writeln( "The shield is too heavy for an ELF." );
  154.    elsif player.shield.count > 0 then
  155.      writeln( "You must first remove the ", player.shield.name );
  156.    else
  157.      L(0) = 1;             ! A shield always needs 1 hand.. !
  158.      S0 = "using";
  159.      goto WR_DOIT;
  160.    endif;
  161.    STOP;
  162.  
  163. :WR_STAFF
  164.    gosub STILLKICKING;
  165.    L(0) = 1;             ! A staff always needs 1 hand.. !
  166.    if player.class = FIGHTER then
  167.      writeln( "Fighters can't use magic staffs." );
  168.    elsif curritem.charges = 0 then
  169.      writeln( "The staff has no charges left.." );
  170.    elsif player.staff.count > 0 then
  171.      writeln( "You must first remove the ", player.staff.name );
  172.    else
  173.      S0 = "holding";
  174.      goto WR_DOIT;
  175.    endif;
  176.    STOP;
  177.  
  178. :WR_AMULET
  179. :WR_RING
  180.    if player.class = FIGHTER then
  181.      writeln( "Fighters can't use magic ", curritem.type, "s." );
  182.    elsif curritem.charges = 0 then
  183.      writeln( "The ", curritem.type, " has no charges left.." );
  184.    elsif curritem.type = AMULET and player.amulet.count > 0 then
  185.      writeln( "You must first remove the ", player.amulet.name );
  186.    elsif curritem.type = RING and player.ring.count > 0 then
  187.      writeln( "You must first remove the ", player.ring.name );
  188.    else
  189.      S0 = "wearing";
  190.      goto WR_DOIT;
  191.    endif;
  192.    STOP;
  193.  
  194. :WR_DOIT
  195.   L(1) = 2; ! Player has 2 hands.. !
  196.   if player.weapon.count then dec( L(1), player.weapon.hands ); endif;
  197.   if player.shield.count then dec( L(1), 1 );                   endif;
  198.   if player.staff.count  then dec( L(1), 1 );                   endif;
  199.   if L(0) > L(1) then
  200.     writeln( "You don't have enough free hands!" );
  201.     STOP;
  202.   endif;
  203.   !
  204.   move( curritem, player.body, 1 );
  205.   if success then
  206.     writeln( "You are now ", s0, " the ", player.body.name );
  207.     if player.body.type = ARMOR or player.body.type = SHIELD then
  208.       if player.armor.cursed or player.shield.cursed then
  209.         player.ac = 0;
  210.       else
  211.         inc(player.ac,player.body.ac);
  212.       endif;
  213.     elsif player.body.type = RING or player.body.type = AMULET then
  214.       if( player.body.charges > 0 ) then
  215.         curritem = player.body;
  216.         gosub M1_INVOKE;
  217.         if curritem.charges < 255 then
  218.           dec( curritem.charges );
  219.         endif;
  220.       else
  221.         writeln( "The ", player.body.type, " has no charges." );
  222.       endif;
  223.     endif;
  224.   endif;
  225.   STOP;
  226.  
  227. !------------------------------------------------------------------------!
  228. :@USE ! Use an object in our backpack...
  229. !------------------------------------------------------------------------!
  230.  
  231.   on curritem.type goto
  232.    USE_FOOD,     USE_WEAPON,     USE_AMMO,      USE_ARMOR,      USE_SHIELD,
  233.    USE_AMULET,   USE_RING,       USE_POTION,    USE_SCROLL,     USE_STAFF,
  234.    USE_CHEST,    USE_KEYS,       USE_GEMS,      USE_BOOK,       USE_GOLDSACK,
  235.    USE_TORCH,    USE_LANTERN,    USE_ROPE,      USE_HOOKS,      USE_MIRROR,
  236.    USE_SIGN,     USE_VEHICLE,    USE_DOOR,      USE_THING;
  237.  
  238.   :USE_THING
  239.   writeln( "I don't know what to do with the ", curritem.name );
  240.   STOP;
  241.  
  242.   :USE_FOOD
  243.   :USE_POTION
  244.   :USE_GEMS
  245.   :USE_SCROLL
  246.      goto @INVOKE;
  247.  
  248.   :USE_AMULET
  249.   :USE_RING
  250.   :USE_ARMOR
  251.   :USE_WEAPON
  252.   :USE_SHIELD
  253.   :USE_STAFF
  254.      goto @WEAR;
  255.  
  256.   :USE_AMMO
  257.      writeln( "Just carry it in your backpack.  If you 'wield' a " );
  258.      writeln( "weapon that uses this type of ammo, it will get used" );
  259.      writeln( "automaticly." );
  260.      STOP;
  261.  
  262.   :USE_CHEST
  263.      ! Unlock the chest !
  264.      if curritem.locktype then
  265.        gosub UNLOCK_OBJECT;
  266.        if curritem.locktype = 0 then
  267.          STOP; 
  268.        endif;
  269.        writeln( "You don't have the right key!  Break the lock?" );
  270.        L0 = select( "Yes", "No" );
  271.        if L0 = 0 then
  272.          if curritem.class <> NORMAL_CHEST then
  273.            writeln( "You can't break this kind of chest." );
  274.          elsif random( 2 + adjustments(player.str) ) > 0 then
  275.            write( "You broke the lock!" );
  276.            if curritem.traptype = 1 then
  277.              voice( "Argh", 1000 );    ! 1000 = DCSOUNDS.VFL !
  278.              writeln( "Argh.. Poison trap!" );
  279.              player.poisoned = 1;
  280.            elsif curritem.traptype > 1 then
  281.              voice( "Explode", 1000 ); ! Play standard sound effect !
  282.              writeln( "Bomb Trap!" );
  283.              dec( player.hp, curritem.damage );
  284.              if player.hp = 0 then
  285.                writeln( player.name, " has died.." );
  286.              endif;
  287.            endif;
  288.            curritem.locktype = 0;
  289.            if curritem.block2 then
  290.              curritem.block = curritem.block2;
  291.            endif;
  292.          else
  293.            writeln( "It doesn't break!" );
  294.          endif;
  295.        else
  296.          writeln( "Ok." );
  297.        endif;
  298.        stats(-1); ! Restore Statistics !
  299.      else
  300.        writeln( "It is not locked.." );
  301.      endif;
  302.      STOP;
  303.  
  304.   :USE_KEYS
  305.      writeln( "All keys are checked when trying to open a door or chest," );
  306.      writeln( "you just have to carry it with you.." );
  307.      STOP;
  308.  
  309.   :USE_BOOK
  310.      goto @LOOK;
  311.  
  312.   :USE_GOLDSACK
  313.      L(1) = getnum("How many gold pieces do you want to put in it?",
  314.                          0, group.gold / 10) * 10;
  315.      if L(1) then
  316.        writeln( "You put ", $L1, " in the bag." );
  317.        inc( curritem.value, L(1) );
  318.        dec( group.gold, L(1) );
  319.      else
  320.        writeln( "Ok.." );
  321.      endif;
  322.      STOP;
  323.  
  324.   :USE_TORCH
  325.   :USE_LANTERN
  326.      writeln( "Save your torches.. I haven't implemented LIGHT yet!" );
  327.      STOP;
  328.  
  329.   :USE_ROPE
  330.      writeln( "After fooling around with it for a while, you manage to" );
  331.      writeln( "get yourself tangled up..." );
  332.      STOP;
  333.  
  334.   :USE_HOOKS
  335.      voice( "Ouch", 1000 );
  336.      writeln( "Ouch! (it's sharp!)" );
  337.      STOP;
  338.  
  339.   :USE_MIRROR
  340.      writeln( "Yes, you are ugly, but that doesn't matter here.." );
  341.      STOP;
  342.  
  343.   :USE_SIGN
  344.      writeln( "If you want to read it, put it back where you found it!" );
  345.      STOP;
  346.  
  347.   :USE_VEHICLE
  348.      writeln( "It would be easyer if you put it down first!" );
  349.      STOP;
  350.  
  351.   :USE_DOOR
  352.      writeln( "Why are you carrying a door?" );
  353.      STOP;
  354.  
  355. !------------------------------------------------------------------------!
  356. :@REMOVE ! Remove an item being worn...
  357. !------------------------------------------------------------------------!
  358.  
  359.   if curritem.cursed then
  360.     writeln( "The ", curritem.type, " is cursed and cannot be removed.." );
  361.     STOP;
  362.   endif;
  363.  
  364.   if player.hp = 0 then
  365.     writeln( player.name, " is dead." );
  366.     STOP;
  367.   endif;
  368.  
  369.   if curritem.type = ARMOR or curritem.type = SHIELD then
  370.     if player.ac > curritem.ac then
  371.       dec(player.ac,curritem.ac);
  372.     else
  373.       player.ac = 0;
  374.     endif;
  375.   elsif curritem.type = RING or curritem.type = AMULET then
  376. writeln("ITEM=",curritem.name," TYPE=", curritem.type, " P=", curritem.permanent );
  377.     if not curritem.permanent then
  378. writeln( "CURRITEM.CLASS=",curritem.class," AC = ", PLUS_AC );
  379.        on curritem.class goto
  380.          XNON, XNON, XNON, XNON, XNON,
  381.          X_STR, X_DEX, X_SPD, X_AIM, X_AC, X_HP, X_IQ, X_PWR;
  382.        goto XNON;
  383.  
  384.        :X_STR if player.str > curritem.units then
  385.                dec(player.str,curritem.units);
  386.              else
  387.                player.str = 0;
  388.              endif;
  389.              goto :XNON;
  390.        :X_DEX if player.DEX > curritem.units then
  391.                dec(player.DEX,curritem.units);
  392.              else
  393.                player.DEX = 0;
  394.              endif;
  395.              goto :XNON;
  396.        :X_SPD if player.SPD > curritem.units then
  397.                dec(player.SPD,curritem.units);
  398.              else
  399.                player.SPD = 0;
  400.              endif;
  401.              goto :XNON;
  402.        :X_AIM if player.AIM > curritem.units then
  403.                dec(player.AIM,curritem.units);
  404.              else
  405.                player.AIM = 0;
  406.              endif;
  407.              goto :XNON;
  408.        :X_AC if player.AC > curritem.units then
  409.                dec(player.AC,curritem.units);
  410.              else
  411.                player.AC = 0;
  412.              endif;
  413.              goto :XNON;
  414.        :X_HP if player.hp > player.mhp then
  415.                if player.hp - curritem.units > player.mhp then
  416.                  dec(player.hp,curritem.units);
  417.                else
  418.                  player.hp = player.mhp; ! No lower than regular max !
  419.                endif;
  420.              endif;
  421.              goto :XNON;
  422.        :X_IQ if player.IQ > curritem.units then
  423.                dec(player.IQ,curritem.units);
  424.              else
  425.                player.IQ = 0;
  426.              endif;
  427.              goto :XNON;
  428.        :X_PWR if player.PWR > curritem.units then
  429.                dec(player.PWR,curritem.units);
  430.              else
  431.                player.PWR = 0;
  432.              endif;
  433.              goto :XNON;
  434.     endif;
  435.     writeln( "BEFORE XNON");
  436. :XNON
  437.     writeln( "AFTER XNON");
  438.   endif;
  439.  
  440.   move( curritem, player.bp, 1 );
  441.   if failure then
  442.     writeln( "ERROR: Couldn't take off the ", curritem.name );
  443.   else
  444.     writeln( player.name, " takes off the ", player.bp.name );
  445.   endif;
  446.   STOP;
  447.  
  448. !------------------------------------------------------------------------!
  449. :@LOOK     ! Finally something we can do!!!! 
  450. !------------------------------------------------------------------------!
  451.   L(255) = FALSE;   ! Set a flag so the subroutine does not give a 
  452.                     ! full description (i.e. LOOK, not EXAMINE)
  453.   gosub DESCRIBE;
  454.   STOP;
  455.  
  456. !------------------------------------------------------------------------!
  457. :@EXAMINE   ! Examine the object in detail                               !
  458. !------------------------------------------------------------------------!
  459.   L(255) = TRUE;   ! Give DETAILED description !
  460.   gosub DESCRIBE;
  461.   STOP;
  462.  
  463. !------------------------------------------------------------------------!
  464. :@INVOKE    ! Invoke an object's magical properties
  465. !------------------------------------------------------------------------!
  466.  
  467. ! Called to use an an object in the current player's backpack.  The
  468. ! action varies depending on the type of object.  For example, food
  469. ! is consumed, potions, amulets, scrolls, etc.  have their magical
  470. ! effect invoked.
  471.  
  472.   gosub STILLKICKING;
  473.   if curritem.endgame = END_ON_USE then
  474.     if curritem.endtext > 0 then         ! .. this text is displayed first.. !
  475.       readtext( curritem.endtext );
  476.     endif;                             ! .. then the game ends. !
  477.     ENDGAME;
  478.   endif;
  479.   if curritem.type = FOOD or curritem.type = POTION then
  480.     player.energy = 255;     ! Not hungry any more.. 
  481.     gosub M1_INVOKE;
  482.     if curritem.type = POTION and curritem.count > 1 then
  483.       curritem.name = curritem.class;
  484.     endif;
  485.     dec( curritem.count );
  486.   elsif curritem.type = SCROLL or curritem.type = STAFF then
  487.     gosub M2_INVOKE;
  488.   elsif curritem.type = GEMS or curritem.type = RING or curritem.type = AMULET then
  489.     gosub M1_INVOKE;
  490.     if curritem.charges < 255 then
  491.       dec( curritem.charges );
  492.       if curritem.count > 1 then
  493.         curritem.name = curritem.class;
  494.       endif;
  495.       if curritem.type = GEMS and curritem.charges = 0 then
  496.         writeln( "The ", curritem.type, " vanishes after you use it." );
  497.         dec( curritem.count );
  498.       endif;
  499.     endif;
  500.   else
  501.     writeln( "The ", curritem.name, " has no magical properties.." );  
  502.   endif;
  503.   STOP;
  504.  
  505. !------------------------------------------------------------------------!
  506. !--  SCRIPT SUBROUTINES ARE GROUPED HERE AT THE END.  THIS IS A CHOICE --!
  507. !--  NOT A REQUIREMENT.  IT MAKES THE MAIN SCRIPT CODE ABOVE A LITTLE  --!
  508. !--  BIT EASIER TO FOLLOW.  ---------------------------------------------!
  509. !------------------------------------------------------------------------!
  510.  
  511.  
  512. !------------------------------------------------------------------------!
  513. ! STILLKICKING: Subroutine to verify that the player is alive before     !
  514. ! allowing him/her/it to perform an action.                              !
  515. !------------------------------------------------------------------------!
  516. :STILLKICKING
  517.   if player.hp = 0 then
  518.     writeln( player.name, " is dead!" );
  519.     STOP;
  520.   endif;
  521.   RETURN;
  522.  
  523.  
  524. !------------------------------------------------------------------------!
  525. !
  526. ! SUBROUTINE: DESCRIBE
  527. !
  528. ! This routine is invoked from @LOOK, @EXAMINE 
  529. !
  530. !------------------------------------------------------------------------!
  531. :DESCRIBE
  532. !------------------------------------------------------------------------!
  533.  
  534.   if curritem.count = 0 then
  535.     writeln( "DBG: Opps. There is nothing to look at in CURRITEM.SCR" );
  536.     STOP;
  537.   endif;
  538.   if curritem.picture >= 0 then
  539.     viewpcx( curritem );
  540.     if success then
  541.       pause;
  542.     endif;
  543.     paint(window); ! Assumes the picture fits in the window !
  544.   elsif curritem.type = SIGN or curritem.type = BOOK then
  545.     readtext( curritem.text );
  546.     STOP;
  547.   endif;
  548.   write( "You see a ", curritem.name );
  549.   if NOT L(255) then
  550.     writeln;
  551.     STOP;
  552.   endif;
  553.   write( ", Type: ", curritem.type );
  554. !
  555. ! The following is a 'cascading if..then..elsif..elsif.....else..endif' 
  556. ! statement.  It is used here to illustrate it's usefulness.  The same
  557. ! code could have been written with a 'ON curritem.type GOTO' statement.
  558. !
  559.   if curritem.type = FOOD or curritem.type = POTION  then
  560.     if curritem.class then
  561.       write( ", Class: ", curritem.class );
  562.       if curritem.class <> CURE then
  563.         write( ", Units: ", curritem.units );
  564.       endif;
  565.     endif;
  566.   elsif curritem.type = WEAPON then
  567.     write( ", Class: ", curritem.class, 
  568.            ", Hands: ", curritem.hands, 
  569.            ", Range: ", curritem.range, 
  570.            ", Damage: ", curritem.damage );
  571.     if curritem.ammoneeded then
  572.       write( ", Needs ammo type: ", curritem.ammo_type );
  573.     endif;
  574.   elsif curritem.type = AMMO then
  575.     write( ", Ammo Type: ", curritem.ammotype );
  576.     if curritem.traptype then
  577.       write( ", Poisoned" );
  578.     endif;
  579.     if curritem.damage then
  580.       write( ", Extra Damage: ", curritem.damage );
  581.     endif;
  582.   elsif curritem.type = ARMOR or curritem.type = SHIELD then
  583.     write( ", Armor Class: ", curritem.ac );
  584.     if curritem.cursed then
  585.       write( " Cursed!" );
  586.     endif;
  587.   elsif curritem.type = AMULET or curritem.type = RING or curritem.type = GEMS then
  588.     if curritem.class then
  589.       write( ", Class: ", curritem.class );
  590.       write( ", Charges: ", curritem.charges );
  591.       if curritem.class <> CURE then
  592.         write( ", Units: ", curritem.units );
  593.         if curritem.permanent then
  594.           write( ", Permanent!" );
  595.         else
  596.           write( ", Temporary" );
  597.         endif;
  598.       endif;
  599.       if curritem.cursed then
  600.         write( ", Cursed!" );
  601.       endif;
  602.     endif;
  603.   elsif curritem.type = SCROLL then
  604.     write( ", Class: ", curritem.class );
  605.   elsif curritem.type = STAFF then
  606.     write( ", Class: ", curritem.class, ", Charges: ", curritem.charges );
  607.   elsif curritem.type = CHEST then
  608.     if curritem.locktype then
  609.       write( ", Locked!" );
  610.       if curritem.traptype = 0 then
  611.         write( ", no traps" );
  612.       elsif curritem.traptype = 1 then
  613.         write( ", poison trap" );
  614.       else
  615.         write( ", bomb damage: ", curritem.traptype );
  616.       endif;
  617.     endif;
  618. ! elsif curritem.type = KEYS     then
  619. !   nothing special about it
  620. ! elsif curritem.type = BOOK     then
  621. !   nothing special about it
  622. ! elsif curritem.type = GOLDSACK then
  623. !   nothing special about it
  624. ! elsif curritem.type = TORCH    then
  625. !   nothing special about it
  626. ! elsif curritem.type = LANTERN  then
  627. !   nothing special about it
  628. ! elsif curritem.type = ROPE     then
  629. !   nothing special about it
  630. ! elsif curritem.type = HOOKS    then
  631. !   nothing special about it
  632. ! elsif curritem.type = MIRROR   then
  633. !   nothing special about it
  634. ! elsif curritem.type = SIGN     then
  635. !   nothing special about it
  636.   elsif curritem.type = VEHICLE then
  637.     write( ", Class: ", curritem.class );
  638. ! else
  639. !   user defined type?
  640.   endif;
  641.   if curritem.weight > 1 and curritem.weight < 256 then
  642.     write( ", Weight: ", curritem.weight );
  643.   endif;
  644.   writeln( "." );
  645.   return;
  646.  
  647. !------------------------------------------------------------------------!
  648. !
  649. ! SUBROUTINE: M1_INVOKE
  650. !
  651. ! Type 1 Magic - Affects the person invoking the magic..
  652. !
  653. ! This portion of the script is invoked whenever an individual in the
  654. ! adventurer's group:
  655. !
  656. !  a) Eats food that has a magical effect
  657. !  b) Drinks a potion with a magical effect
  658. !  c) Successfully wears a ring or an amulet with a magical effect
  659. !  d) Uses a GEM that has a magical effect.
  660. !
  661. ! When invoked, PLAYER is the person that will be affected, and CURRITEM
  662. ! is the item that has the magical effect, and which is either being
  663. ! worn or in the character's backpack.  OBJECT and NPC are not defined.
  664. !
  665. !------------------------------------------------------------------------!
  666. :M1_INVOKE
  667. !------------------------------------------------------------------------!
  668.  
  669.   if curritem.cursed and curritem.permanent then
  670.     curritem.permanent = FALSE;
  671.     writeln( "WARNING: This object was 'cursed' and had 'permanent' effect!" );
  672.     writeln( "WARNING: The effect has been made 'temporary' by OBJECT.SCR" );
  673.   endif;
  674.  
  675.   on curritem.class goto
  676.     M1_NONE,    M1_CURE,    M1_HEAL,    M1_POISON,    M1_RESTORE,
  677.     M1_STR,     M1_DEX,     M1_SPD,     M1_AIM,       M1_AC,
  678.     M1_HP,      M1_IQ,      M1_PWR;
  679.  
  680. :M1_NONE
  681.   writeln( "Nothing happens.." );
  682.   return;
  683.  
  684. :M1_CURE
  685.   if player.poisoned then
  686.     player.poisoned = 0;
  687.     writeln( player.name, " is now cured." );
  688.   else
  689.     writeln( "Nothing happens.." );
  690.   endif;
  691.   return;
  692.  
  693. :M1_HEAL
  694.   if player.hp >= player.mhp then
  695.     writeln( "Nothing happens.." );
  696.   elsif player.hp = 0 then
  697.     writeln( player.name, " is beyond help.." );
  698.   else
  699.     if curritem.units > 0 then
  700.       L(0) = curritem.units;                   ! always heals the same points !
  701.     else
  702.       L(0) = random(player.mhp - player.hp)+1; ! heal a random number of points !
  703.     endif;
  704.     voice( "Tada", 1000 );
  705.     if player.hp + L(0) < player.mhp then
  706.       writeln( player.name, " heals ", L(0), " hit points.." );
  707.       inc( player.hp, L(0) );
  708.     else
  709.       writeln( player.name, " has been completely healed!" );
  710.       player.hp = player.mhp;
  711.     endif;
  712.   endif;
  713.   return;
  714.  
  715. :M1_POISON
  716.   if NOT player.poisoned then
  717.     player.poisoned = 1;
  718.     voice( "Boing", 1000 );
  719.     writeln( "You feel sick.." );
  720.   else
  721.     voice( "Boing", 1000 );
  722.     writeln( "You feel worse.." );
  723.   endif;
  724.   return;
  725.  
  726. :M1_RESTORE
  727.   if player.hp >= player.mhp then
  728.     writeln( "Nothing happens.." );
  729.   elsif player.hp = 0 then
  730.     writeln( player.name, " is beyond help.." );
  731.   else
  732.     voice( "okspell", 1000 );
  733.     player.hp = player.mhp;
  734.     writeln( player.name, " is completely healed!" );
  735.   endif;
  736.   return;
  737.  
  738. :M1_STR
  739.   if curritem.cursed then
  740.     player.str = 0;
  741.     voice( "BOING", 1000 );
  742.     writeln( "Something went wrong.." );
  743.   else
  744.     voice( "okspell", 1000 );
  745.     inc( player.str, curritem.units );
  746.     if curritem.permanent then
  747.       inc( player.mstr, curritem.units );
  748.     endif;
  749.     writeln( player.name, "'s strength increased by ", curritem.units, "!" );
  750.   endif;
  751.   return;
  752.  
  753. :M1_DEX
  754.   if curritem.cursed then
  755.     player.dex = 0;
  756.     voice( "BOING", 1000 );
  757.     writeln( "Something went wrong.." );
  758.   else
  759.     voice( "okspell", 1000 );
  760.     inc( player.dex, curritem.units );
  761.     if curritem.permanent then
  762.       inc( player.mdex, curritem.units );
  763.     endif;
  764.     writeln( player.name, "'s dexterity increased by ", curritem.units, "!" );
  765.   endif;
  766.   return;
  767.  
  768. :M1_SPD
  769.   if curritem.cursed then
  770.     player.spd = 0;
  771.     voice( "BOING", 1000 );
  772.     writeln( "Something went wrong.." );
  773.   else
  774.     voice( "okspell", 1000 );
  775.     inc( player.spd, curritem.units );
  776.     if curritem.permanent then
  777.       inc( player.mspd, curritem.units );
  778.     endif;
  779.     writeln( player.name, "'s speed increased by ", curritem.units, "!" );
  780.   endif;
  781.   return;
  782.  
  783. :M1_AIM
  784.   if curritem.cursed then
  785.     player.aim = 0;
  786.     voice( "BOING", 1000 );
  787.     writeln( "Something went wrong.." );
  788.   else
  789.     voice( "okspell", 1000 );
  790.     inc( player.aim, curritem.units );
  791.     if curritem.permanent then
  792.       inc( player.maim, curritem.units );
  793.     endif;
  794.     writeln( player.name, "'s aim increased by ", curritem.units, "!" );
  795.   endif;
  796.   return;
  797.  
  798. :M1_AC
  799.   if curritem.cursed then
  800.     player.ac = 0;
  801.     voice( "BOING", 1000 );
  802.     writeln( "Something went wrong.." );
  803.   else
  804.     voice( "okspell", 1000 );
  805.     inc( player.ac, curritem.units );
  806.     if curritem.permanent then
  807.       inc( player.mac, curritem.units );
  808.     endif;
  809.     writeln( player.name, "'s armor class increased by ", curritem.units, "!" );
  810.   endif;
  811.   return;
  812.  
  813. :M1_HP
  814.   if curritem.cursed then
  815.     player.hp = player.hp / 3 + 1;
  816.     writeln( player.name, " has been seriously injured!" );
  817.   else
  818.     voice( "okspell", 1000 );
  819.     inc( player.hp, curritem.units );
  820.     if curritem.permanent then
  821.       inc( player.mhp, curritem.units );
  822.     endif;
  823.     writeln( player.name, "'s hit points increased by ", curritem.units, "!" );
  824.   endif;
  825.   return;
  826.  
  827. :M1_IQ
  828.   if curritem.cursed then
  829.     player.iq = 0;
  830.     voice( "BOING", 1000 );
  831.     writeln( "Something went wrong.." );
  832.   else
  833.     voice( "okspell", 1000 );
  834.     inc( player.iq, curritem.units );
  835.     if curritem.permanent then
  836.       inc( player.miq, curritem.units );
  837.     endif;
  838.     writeln( player.name, "'s i.q. increased by ", curritem.units, "!" );
  839.   endif;
  840.   return;
  841.  
  842. :M1_PWR
  843.   if player.class = ELF or player.class = WIZARD then
  844.     if curritem.cursed then
  845.       player.pwr = 0;
  846.       voice( "BOING", 1000 );
  847.       writeln( "Something went wrong.." );
  848.     else
  849.       inc( player.pwr, curritem.units );
  850.       if curritem.permanent then
  851.         inc( player.mpwr, curritem.units );
  852.       endif;
  853.       voice( "okspell", 1000 );
  854.       writeln( player.name, "'s power increased by ", curritem.units, "!" );
  855.     endif;
  856.   else
  857.     voice( "Argh", 1000 );
  858.     write( player.name, " screams and falls to the ground, " );
  859.     if player.hp < 3 then
  860.       writeln( "dead!" );
  861.       player.hp = 0;
  862.     else
  863.       writeln( "holding his head.." );
  864.       dec( player.hp, 2 );
  865.     endif;
  866.   endif;
  867.   return;
  868.  
  869. !------------------------------------------------------------------------!
  870. !
  871. ! SUBROUTINE: M2_INVOKE
  872. !
  873. ! Type 2 Magic - Affects an object or a another person
  874. !
  875. ! This portion of the script handles magic spells which affect objects
  876. ! or persons other than the caster.  When invoked, the PLAYER is the
  877. ! person that invoked the spell and CURRITEM is the object that was used
  878. ! to invoke the spell (which is either being worn or carried by the
  879. ! player).
  880. !
  881. ! The OBJECT and NPC are undefined.  If the spell requires a target,
  882. ! the 'LOCATE' function can be used to select an object or character
  883. ! to cast the spell on.  The locate function returns the distance in blocks
  884. ! to the selected target.  If none is selected, the value is -1, and FAILURE
  885. ! is set.
  886. !
  887. ! After a LOCATE, either OBJECT or NPC will be set depending on whether the
  888. ! user selected an object or a character (or monster, during a fight).
  889. !
  890. ! To figure out which one was selected, check if NPC.COUNT is greater than
  891. ! 0.  If it is, a character was selected.  If it is not, then an object was
  892. ! selected.
  893. !
  894. !------------------------------------------------------------------------!
  895. :M2_INVOKE
  896. !------------------------------------------------------------------------!
  897.  
  898.   if curritem.class = NONE then
  899.     writeln( "Nothing happens.." );
  900.     return;
  901.   endif;
  902.  
  903.   if curritem.count = 0 then
  904.     writeln( "Oops, no object in OBJECT.SCR, m2 invoke" );
  905.     stop;
  906.   endif;
  907.  
  908.   if curritem.class = DAMAGE or curritem.class = CONFUSE or
  909.      curritem.class = SCARE  or curritem.class = PARALYZE or
  910.      curritem.class = KILL then
  911.     if not fighting then
  912.       writeln( "This spell can only be used during a fight.." );
  913.       return;
  914.     endif;
  915.     !
  916.     ! L(5) will contain the TOTAL experience points gained when done..
  917.     ! L(6) is the maximum damage that will be done to a single monster..
  918.     ! L(8) is the maximum total damage that can be done to a group of monsters..
  919.     ! L(9) is the TOTAL number of monsters affected AFTER the spell
  920.     !
  921.     L(5) = 0;
  922.     L(6) = player.level + adjustments(player.pwr) / 2 + 1;
  923.     if L(6) <= 0 then
  924.       writeln( "The spell failed.." );
  925.       STOP;
  926.     endif;
  927.     if curritem.units then
  928.       L(8) = curritem.units;
  929.     else
  930.       L(8) = player.iq + adjustments(player.iq);
  931.     endif;
  932.     L(9) = 0;
  933.   endif;
  934.  
  935.   if curritem.type = STAFF and curritem.charges = 0 then
  936.     writeln( "The ", curritem.name, " doesn't work.." );
  937.     return;
  938.   endif;
  939.      
  940.   if curritem.class <> LEAVE  and
  941.      curritem.class <> ZOOM   and
  942.      curritem.class <> INFORM and
  943.      curritem.class <> DOORS  and
  944.      curritem.class <> RESURRECT then
  945.     write( curritem.class, " what:" );
  946.     L(1) = locate;  ! SETS THE TARGET FOR THE SPELL ! 
  947.     if L(1) = 0 then
  948.       writeln( "nothing.." );
  949.       return;
  950.     endif;
  951.     ! Either NPC.COUNT or OBJECT.COUNT identifies selected object/char !
  952.     if npc.count then ! It's a character, not an object..
  953.       if npc.type = HOSTILE then
  954.         writeln( npc.name );  ! monster's don't have classes.. !
  955.       else
  956.         writeln( npc.class ); ! Human, elf, dwarf, etc..       !
  957.       endif;
  958.       if curritem.class = DESTROY  or curritem.class = DUPLICATE or
  959.          curritem.class = RECHARGE or curritem.class = FLOAT then
  960.         writeln( "This spell only work's on objects!" );
  961.         goto M2_EXIT;
  962.       endif;
  963.     else
  964.       writeln( object.type );  ! Food, weapon, ring, etc..      !
  965.     endif;
  966.   endif;
  967.  
  968.   on curritem.class goto 
  969.     M2_EXIT,     M2_DESTROY,  M2_DUPLICATE, M2_LEAVE,
  970.     M2_RESURRECT,M2_INFORM,   M2_LOCATE,    M2_KILL, 
  971.     M2_CONFUSE,  M2_SCARE,    M2_DAMAGE,    M2_PARALYZE,
  972.     M2_RECHARGE, M2_FLOAT,    M2_ANALYZE,   M2_ZOOM;
  973.  
  974. :M2_NONE      ! No magic..
  975.   writeln( "Nothing happens.." );
  976.   goto M2_EXIT;
  977.  
  978. :M2_DESTROY   ! Destroy an object                      pwr = 5, rng=10
  979.   ! if player.pwr < 5 goto M2_NOPOWER; ! No power check needed
  980.   if L(1) > 10 goto M2_OUTOFRANGE;
  981.   voice( "Explode", 1000 );
  982.   writeln( "The ", object.type, " is destroyed.." );
  983.   vanish( object );
  984.   L(4) = 5;
  985.   goto M2_EXIT;
  986.  
  987. :M2_DUPLICATE ! Duplicates an object                   pwr = 40, rng=1
  988.   ! if player.pwr < 40 goto M2_NOPOWER; ! No power check needed
  989.   if L(1) > 1 goto M2_OUTOFRANGE;
  990.   inc( object.count, 1 ); ! Creates an identical copy ! 
  991.   L(4) = 40;
  992.   goto M2_EXIT;
  993.  
  994. :M2_LEAVE     ! Exit through the 'exit' door from anywhere...  
  995.   if world.type <> DUNGEON then
  996.     voice( "Boing", 1000 );
  997.     writeln( "This spell only work's in dungeons.." );
  998.     return;
  999.   endif;
  1000.   ! if player.pwr < 5 goto M2_NOPOWER; ! No power check needed
  1001.   enter( world.edgedoor );
  1002.   voice( "okspell", 1000 );
  1003.   writeln( "You leave this level of the dungeon.." );
  1004.   L(4) = 5;
  1005.   goto M2_EXIT;
  1006.  
  1007. :M2_RESURRECT ! Revive a DEAD person                   pwr = 50, rng=1
  1008.   ! if player.pwr < 50 goto M2_NOPOWER; ! No power check needed
  1009.   if L(1) > 1 goto M2_OUTOFRANGE;
  1010.   write( "Resurrect: " );
  1011.   L0 = select( group );
  1012.   stats( L0 );
  1013.   if player.hp > 0 then
  1014.     voice( "Boing", 1000 );
  1015.     writeln( "This player is NOT dead!" );
  1016.     return;
  1017.   endif;
  1018.   voice( "okspell", 1000 );
  1019.   writeln( player.name );
  1020.   player.hp  = 2;
  1021.   writeln( player.name, " is alive, but weak.." );
  1022.   L(4) = 50;
  1023.   goto M2_EXIT;
  1024.   
  1025. :M2_INFORM    ! Displays some text                     pwr =  5
  1026.   ! if player.pwr < 5 goto M2_NOPOWER; ! No power check needed
  1027.   if L(1) > 5 goto M2_OUTOFRANGE;
  1028.   loadhint;
  1029.   writeln( "The wind seems to carry a random phrase to your ears.." );
  1030.   writeln( s0 );
  1031.   L(4) = 5;
  1032.   goto M2_EXIT;
  1033.  
  1034. :M2_LOCATE    ! Locate doors                           pwr = 10
  1035.   ! if player.pwr < 10 goto M2_NOPOWER; ! No power check needed
  1036.   if L(1) > 10 goto M2_OUTOFRANGE;
  1037.   L(0) = 0;
  1038.   :LDLOOP
  1039.     if world.doorx(L0) > 0 and world.doory(L0) > 0 then
  1040.       frame( world.doorx(L0), world.doory(L0), SYS_FRAME );
  1041.     endif;
  1042.     inc(L0);
  1043.   if L(0) < 16 goto LDLOOP;
  1044.   L(4) = 10;
  1045.   goto M2_EXIT;
  1046.  
  1047. :M2_KILL      ! Kill 1 enemy during battle             pwr = 20, rng=6
  1048.   writeln( npc.name, " killed. +", npc.hp, " exp." );
  1049.   inc( player.exp, npc.hp );
  1050.   npc.count = 0;
  1051.   STOP;
  1052.  
  1053. :M2_DAMAGE    ! Causes damage to monsters              pwr =  5, rng=12
  1054.   S0 = "hit";
  1055.   foreach npc do
  1056.     L(7) = min( npc.hp, random(L6) );  ! How much damage to this one monster?
  1057.     if L(7) > 0 then
  1058.       frame(npc.x, npc.y, SYS_SPLAT); wait(1); frame(npc.x, npc.y, SYS_SPLAT);
  1059.       write( npc.name );
  1060.       if L(7) < npc.hp then
  1061.         write( " hit." );
  1062.         dec( npc.hp, L(7) );           ! Hit the monster..
  1063.       else
  1064.         write( " killed!" );
  1065.         npc.count = 0;
  1066.       endif;
  1067.       writeln( " +", L(7), " exp." );
  1068.       inc(L9);                       ! Count of affected npcs
  1069.       inc( L(5), L(7) );                 ! Accumulate experience..
  1070.       if L(5) > L(8) goto DCSPEXIT;      ! Stop when total of L(8) points used
  1071.     endif;
  1072.   endfor;  
  1073.   goto DCSPEXIT;
  1074.  
  1075. :M2_CONFUSE   ! Makes monsters shoot at other monsters pwr =  1, rng=12
  1076.   S0 = "confused";
  1077.   foreach npc do
  1078.     L(7) = min( npc.hp, random(L6) );  ! How much confusion to this one monster?
  1079.     if L(7) > 0 and npc.confused = 0 then
  1080.       frame(npc.x, npc.y, SYS_SPLAT); wait(1); frame(npc.x, npc.y, SYS_SPLAT);
  1081.       inc(L9);                       ! Count of affected npcs
  1082.       npc.confused = L(7);             ! Confuse for 'n' units
  1083.       inc( L(5), L(7) );                 ! Accumulate experience..
  1084.       if L(5) > L(8) goto DCSPEXIT;      ! Stop when total of L(8) points used
  1085.     endif;
  1086.   endfor;  
  1087.   goto DCSPEXIT;
  1088.  
  1089. :M2_SCARE     ! Scares monsters                        pwr =  2, rng=12
  1090.   S0 = "scared";
  1091.   foreach npc do
  1092.     L(7) = min( npc.hp, random(L6) );  ! How much 'fright' to this one monster?
  1093.     if L(7) > 0 and npc.scared = 0 then
  1094.       frame(npc.x, npc.y, SYS_SPLAT); wait(1); frame(npc.x, npc.y, SYS_SPLAT);
  1095.       inc(L9);
  1096.       npc.scared = L(7);               ! Frighten for 'n' units
  1097.       inc( L(5), L(7) );                 ! Accumulate experience..
  1098.       if L(5) > L(8) goto DCSPEXIT;      ! Stop when total of L(8) points used
  1099.     endif;
  1100.   endfor;  
  1101.   goto DCSPEXIT;
  1102.  
  1103. :M2_PARALYZE  ! Monster can't move                     pwr =  5, rng=12
  1104.   S0 = "paralyzed";
  1105.   foreach npc do
  1106.     L(7) = min( npc.hp, random(L6) );  ! How much paralysis to this one monster?
  1107.     if L(7) > 0 and npc.paralyzed = 0 then
  1108.       frame(npc.x, npc.y, SYS_SPLAT); wait(1); frame(npc.x, npc.y, SYS_SPLAT);
  1109.       inc(L9);
  1110.       npc.paralyzed = L(7);            ! Paralyze for 'n' units
  1111.       inc( L(5), L(7) );                 ! Accumulate experience..
  1112.       if L(5) > L(8) goto DCSPEXIT;      ! Stop when total of L(8) points used
  1113.     endif;
  1114.   endfor;  
  1115.   goto DCSPEXIT;
  1116.  
  1117. :M2_RECHARGE  ! Recharge an ITEM                       pwr = 25, rng=1
  1118.   ! if player.pwr < 25 goto M2_NOPOWER; ! No power check needed
  1119.   if L(1) > 1 goto M2_OUTOFRANGE;
  1120.   if object.type = RING or object.type = AMULET or object.type = STAFF then
  1121.     inc( object.charges, random(player.level)+1 );
  1122.     voice( "okspell", 1000 );
  1123.     writeln( "The ", object.type, " now has ", object.charges, " charges." );
  1124.   else
  1125.     voice( "Boing", 1000 );
  1126.     writeln( "The smell of rotten eggs fills the air.." );
  1127.   endif;
  1128.   L(4) = 25;
  1129.   goto M2_EXIT;
  1130.  
  1131. :M2_FLOAT     ! Remove an object's weight              pwr = 10, rng=1
  1132.   ! if player.pwr < 10 goto M2_NOPOWER; ! No power check needed
  1133.   if L(1) > 1 goto M2_OUTOFRANGE;
  1134.   if object.weight < 255 then
  1135.     object.weight = object.weight / 2 + 1;
  1136.     voice( "okspell", 1000 );
  1137.     writeln( "The ", object.type, " is now much lighter.." );
  1138.   else
  1139.     voice( "Boing", 1000 );
  1140.     writeln( "It's didn't work.  The ", object.type, " is too heavy." );
  1141.   endif;
  1142.   L(4) = 10;
  1143.   goto M2_EXIT;
  1144.  
  1145. :M2_ANALYZE   ! Discover object's properties           pwr = 10, rng=1
  1146.   ! if player.pwr < 10 goto M2_NOPOWER; ! No power check needed
  1147.   if L(1) > 1  goto M2_OUTOFRANGE;
  1148.   L(255) = TRUE;   ! Give DETAILED description !
  1149.   gosub DESCRIBE;
  1150.   L(4) = 10;
  1151.   goto M2_EXIT;
  1152.  
  1153. :M2_ZOOM      ! View the world.. 
  1154.   ! if player.pwr < 25 goto M2_NOPOWER; ! No power check needed
  1155.   viewpcx( world );
  1156.   if success then
  1157.     pause;
  1158.   endif;
  1159.   paint( screen ); ! If you don't have any WORLD###.PCX files, you can use !
  1160.                    ! paint( WINDOW ) instead of paint( SCREEN) !
  1161.   L(4) = 25;
  1162.   goto M2_EXIT;
  1163.  
  1164. :M2_NOPOWER
  1165.   writeln( "You don't have enough power!" );
  1166.   return;
  1167.  
  1168. :M2_OUTOFRANGE
  1169.   writeln( "You are too far away from the ", object.name );
  1170.   return;
  1171.  
  1172. :DCSPEXIT
  1173.   if L(9) then
  1174.     write( L(9), " foes were ", S0 );
  1175.     if L(5) then  
  1176.       writeln( " for a total of +", L(5), " experience!" );
  1177.       inc( player.exp, L(5) );           ! Grant experience..
  1178.     else
  1179.       writeln( " With no effect" );
  1180.     endif;
  1181.   else
  1182.     writeln( "No effect.." );
  1183.   endif;
  1184.   goto M2_EXIT;
  1185.  
  1186. :M2_EXIT
  1187.   if curritem.count > 0 then
  1188.     if curritem.count > 1 then
  1189.       curritem.name = curritem.class;
  1190.     endif;
  1191.     if curritem.type = SCROLL then
  1192.       dec( curritem.count ); ! Item disapears if count reaches 0 !
  1193.     elsif curritem.type = STAFF then
  1194.       dec( curritem.charges ); ! One less !
  1195.     endif;
  1196.   else
  1197.     dec( player.pwr, L(4) );   ! A spell !
  1198.   endif;
  1199.   return;
  1200.  
  1201. !------------------------------------------------------------------------!
  1202. :UNLOCK_OBJECT
  1203. !------------------------------------------------------------------------!
  1204.    L0 = 0;
  1205.    L1 = curritem.index;
  1206.    L2 = curritem.locktype;
  1207.    :UCLOOP
  1208.       setbp( player, L0 );
  1209.       if player.bp.count then
  1210.         if player.bp.type = KEYS and player.bp.keytype = L2 then
  1211.           write( "You use the ", player.bp.name, " to unlock the " );
  1212.           setbp( player, L1 ); ! Recover the 'curritem' !
  1213.           writeln( curritem.name );
  1214.           curritem.locktype = 0;
  1215.           if curritem.block2 then
  1216.             L0 = curritem.block2;
  1217.             curritem.block  = curritem.block2;
  1218.             curritem.block2 = L0;
  1219.           endif;
  1220.           return;
  1221.         endif;
  1222.       endif;
  1223.       inc( L0 );
  1224.       if L0 < 16 goto :UCLOOP;
  1225.    RETURN;
  1226.  
  1227.  
  1228.